// Parameter
res=200; // Auflösung
da=160;  // Außendurchmesser
di=150;  // Innendurchmesser
a=3;     // Wanddicke
b=10;    // Fugenhöhe

//-------------------

$fn=res;
rad=da/2+6;

difference() {
   union() {
      // Außenring
      difference() {
         union() {
            translate([0,0,0]) cylinder(h=a+b, d=da+a);
            //Flansche außen
            linear_extrude(height = b+a, center = false, convexity = 10, twist = 0) {
               hull() {
                  for (i=[0:120:359]) {
                     translate([rad*cos(i),rad*sin(i),0])circle(d=12);
                  }
               }
            }
         }
         // Dickere Decke im Spalt
         translate([0,0,-0.1]) cylinder(h=b+0.1-1, d=da);
         translate([0,0,-0.1]) cylinder(h=b+0.1, d=di);
         // Flanschloch
         for (i=[0:120:359]) {
            translate([rad*cos(i),rad*sin(i),-0.1])cylinder(h=b+a+5+0.2, d=6, center=false);
         }
      }
      // Innenring
      difference() {
          translate([0,0,-0.1]) cylinder(h=b+0.2, d=di);
          translate([0,0,-0.2]) cylinder(h=b+0.1, d=di-a);
      }
   }
   // Spalt für Oberen Deckel
   translate([0,0,b+a-1])difference() {
       translate([0,0,0]) cylinder(h=1.1, d=di+(da-di)/2+a/2);
       translate([0,0,-0.1]) cylinder(h=1+0.2, d=di+(da-di)/2-a/2);
   }
   // Einkerbung Laserplatine
   translate([-15,45,a+b-0.9]) difference() {
       cube([30,11,1]);
       translate([0,0,0])cube([4.1,2.2,1.1]);
       translate([26,0,0])cube([4.1,2.2,1.1]);
       translate([26,8.8,0])cube([4.1,2.2,1.1]);
       translate([0,8.8,0])cube([4.1,2.2,1.1]);
   }    
   // Loch für Laser
   translate([-2.5,50,-0.3]) cube([5,4,a+b+0.6]);
}