debian/notmuch
1
0
Fork 0
mirror of https://git.notmuchmail.org/git/notmuch synced 2024-11-21 18:38:08 +01:00
Code Issues Projects Releases Packages Wiki Activity Actions

emacs: add `notmuch-show-stash-mlarchive-link{, -and-go}'

Browse source 
* emacs/notmuch-show.el

  (notmuch-show-stash-mlarchive-link-alist):
    New defcustom of type `alist' (key = name, value = URI),
    containing Mailing List Archive URI's for searching by Message-Id.

  (notmuch-show-stash-mlarchive-link-default):
    New defcustom, default MLA to use when `notmuch-show-stash-mlarchive-link'
    received no user input whatsoever.  Available choices are generated using
    the contents of `notmuch-show-stash-mlarchive-link-alist'.

  (notmuch-show-stash-map):
    Added keybinds "l" and "L" for `notmuch-show-stash-mlarchive-link'
    respectively `notmuch-show-stash-mlarchive-link-and-go'.

  (notmuch-show-stash-mlarchive-link):
    New function, stashes a URI pointing to the current message at one
    of the MLAs configured in `notmuch-show-stash-mlarchive-link-alist'.
    Prompts user with `completing-read' if not provided with an MLA key.

  (notmuch-show-stash-mlarchive-link-and-go):
    New function, uses `notmuch-show-stash-mlarchive-link' to
    stash a URI, and then visits it using the browser configured
    in `browse-url-browser-function'.

Based on original work [1] by David Edmondson <dme@dme.org>.

[1] id:"1327397873-20596-1-git-send-email-dme@dme.org"
This commit is contained in:
Pieter Praet 2012-02-19 21:50:27 +01:00 committed by David Bremner
parent e2a68f9941
commit 2f86290aaf
2 changed files with 61 additions and 1 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

61
emacs/notmuch-show.el
View file

@ -155,6 +155,35 @@ indentation."
(make-variable-buffer-local 'notmuch-show-indent-content)
(put 'notmuch-show-indent-content 'permanent-local t)
(defcustom notmuch-show-stash-mlarchive-link-alist
'(("Gmane" . "http://mid.gmane.org/")
("MARC" . "http://marc.info/?i=")
("Mail Archive, The" . "http://mail-archive.com/search?l=mid&q=")
;; FIXME: can these services be searched by `Message-Id' ?
;; ("MarkMail" . "http://markmail.org/")
;; ("Nabble" . "http://nabble.com/")
;; ("opensubscriber" . "http://opensubscriber.com/")
)
"List of Mailing List Archives to use when stashing links.
These URIs are concatenated with the current message's
Message-Id in `notmuch-show-stash-mlarchive-link'."
:type '(alist :key-type (string :tag "Name")
:value-type (string :tag "URL"))
:group 'notmuch-show)
(defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
"Default Mailing List Archive to use when stashing links.
This is used when `notmuch-show-stash-mlarchive-link' isn't
provided with an MLA argument nor `completing-read' input."
:type `(choice
,@(mapcar
(lambda (mla)
(list 'const :tag (car mla) :value (car mla)))
notmuch-show-stash-mlarchive-link-alist))
:group 'notmuch-show)
(defmacro with-current-notmuch-show-message (&rest body)
"Evaluate body with current buffer set to the text of current message"
`(save-excursion
@ -1149,6 +1178,8 @@ buffer is stored and re-applied after the refresh."
(define-key map "s" 'notmuch-show-stash-subject)
(define-key map "T" 'notmuch-show-stash-tags)
(define-key map "t" 'notmuch-show-stash-to)
(define-key map "l" 'notmuch-show-stash-mlarchive-link)
(define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
map)
"Submap for stash commands")
(fset 'notmuch-show-stash-map notmuch-show-stash-map)
@ -1815,6 +1846,36 @@ thread from search."
(interactive)
(notmuch-common-do-stash (notmuch-show-get-to)))
(defun notmuch-show-stash-mlarchive-link (&optional mla)
"Copy an ML Archive URI for the current message to the kill-ring.
This presumes that the message is available at the selected Mailing List Archive.
If optional argument MLA is non-nil, use the provided key instead of prompting
the user (see `notmuch-show-stash-mlarchive-link-alist')."
(interactive)
(notmuch-common-do-stash
(concat (cdr (assoc
(or mla
(let ((completion-ignore-case t))
(completing-read
"Mailing List Archive: "
notmuch-show-stash-mlarchive-link-alist
nil t nil nil notmuch-show-stash-mlarchive-link-default)))
notmuch-show-stash-mlarchive-link-alist))
(notmuch-show-get-message-id t))))
(defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
"Copy an ML Archive URI for the current message to the kill-ring and visit it.
This presumes that the message is available at the selected Mailing List Archive.
If optional argument MLA is non-nil, use the provided key instead of prompting
the user (see `notmuch-show-stash-mlarchive-link-alist')."
(interactive)
(notmuch-show-stash-mlarchive-link mla)
(browse-url (current-kill 0 t)))
;; Commands typically bound to buttons.
(defun notmuch-show-part-button-default (&optional button)

1
test/emacs
View file

@ -384,7 +384,6 @@ test_emacs '(notmuch-show "id:f35dbb950911171438k5df6eb56k77b6c0944e2e79ae@mail.
test_expect_equal_file OUTPUT $EXPECTED/notmuch-show-thread-with-hidden-messages
test_begin_subtest "Stashing in notmuch-show"
test_subtest_known_broken
add_message '[date]="Sat, 01 Jan 2000 12:00:00 -0000"' \
'[from]="Some One <someone@somewhere.org>"' \
'[to]="Some One Else <notsomeone@somewhere.org>"' \