mirror of
https://git.notmuchmail.org/git/notmuch
synced 2024-11-24 11:58:10 +01:00
c2f3710a78
Initially this file provides one main function
notmuch-query-get-threads, which takes a set of search terms, and
returns a parsed set of matching threads as a lisp data structure.
A set of notmuch-query-map-* functions are provided to help map
functions over the data structure.
The function notmuch-query-get-message-ids uses this machinery to get
the set of message-ids matching a query.
Edited-by: Carl Worth <cworth@cworth.org>: Change comment syntax,
(";;" rather than ";" to make emacs-lisp mode happy), and eliminate
some excess whitespace, as suggested by David Edmonson.
81 lines
2.8 KiB
EmacsLisp
81 lines
2.8 KiB
EmacsLisp
;; notmuch-query.el --- provide an emacs api to query notmuch
|
|
;;
|
|
;; Copyright © David Bremner
|
|
;;
|
|
;; This file is part of Notmuch.
|
|
;;
|
|
;; Notmuch is free software: you can redistribute it and/or modify it
|
|
;; under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
;;
|
|
;; Notmuch is distributed in the hope that it will be useful, but
|
|
;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
;; General Public License for more details.
|
|
;;
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with Notmuch. If not, see <http://www.gnu.org/licenses/>.
|
|
;;
|
|
;; Authors: David Bremner <david@tethera.net>
|
|
|
|
(require 'notmuch-lib)
|
|
(require 'json)
|
|
|
|
(defun notmuch-query-get-threads (search-terms &rest options)
|
|
"Return a list of threads of messages matching SEARCH-TERMS.
|
|
|
|
A thread is a forest or list of trees. A tree is a two element
|
|
list where the first element is a message, and the second element
|
|
is a possibly empty forest of replies.
|
|
"
|
|
(let ((args (append '("show" "--format=json") search-terms))
|
|
(json-object-type 'plist)
|
|
(json-array-type 'list)
|
|
(json-false 'nil))
|
|
(with-temp-buffer
|
|
(progn
|
|
(apply 'call-process (append (list notmuch-command nil t nil) args))
|
|
(goto-char (point-min))
|
|
(json-read)))))
|
|
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
;; Mapping functions across collections of messages.
|
|
|
|
(defun notmuch-query-map-aux (mapper function seq)
|
|
"private function to do the actual mapping and flattening"
|
|
(apply 'append
|
|
(mapcar
|
|
(lambda (tree)
|
|
(funcall mapper fn tree))
|
|
seq)))
|
|
|
|
(defun notmuch-query-map-threads (fn threads)
|
|
"apply FN to every thread in THREADS. Flatten results to a list.
|
|
|
|
See the function notmuch-query-get-threads for more information."
|
|
(notmuch-query-map-aux 'notmuch-query-map-forest fn threads))
|
|
|
|
(defun notmuch-query-map-forest (fn forest)
|
|
"apply function to every message in a forest. Flatten results to a list.
|
|
|
|
See the function notmuch-query-get-threads for more information.
|
|
"
|
|
(notmuch-query-map-aux 'notmuch-query-map-tree fn forest))
|
|
|
|
(defun notmuch-query-map-tree (fn tree)
|
|
"Apply function FN to every message in TREE. Flatten results to a list
|
|
|
|
See the function notmuch-query-get-threads for more information."
|
|
(cons (funcall fn (car tree)) (notmuch-query-map-forest fn (cadr tree))))
|
|
|
|
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
|
|
;; Predefined queries
|
|
|
|
(defun notmuch-query-get-message-ids (&rest search-terms)
|
|
"Return a list of message-ids of messages that match SEARCH-TERMS"
|
|
(notmuch-query-map-threads
|
|
(lambda (msg) (plist-get msg :id))
|
|
(notmuch-query-get-threads search-terms)))
|
|
|
|
(provide 'notmuch-query)
|